第30课 RunApp启动运行程序 - 《按键精灵9 · 经典教程》

//高级例子1
//介绍: 部分应用程序无法使用RunApp命令打开, 故这里提供一个API启动程序命令
//程序路径: 要启动程序的完整路径
//下面两行是API的声明, 请放在脚本开头
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal Hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
Sub zmRunApp(程序路径)
    Dim p, DirPath, FileName
    p = InStrRev(程序路径, "\")
    DirPath = Left(程序路径, p)
    FileName = Right(程序路径, Len(程序路径) - p)
    ShellExecute GetDesktopWindow, "open", FileName, vbNullString, DirPath, 5
End Sub

//调用例子如下:
zmRunApp "C:\Program Files (x86)\Tencent\QQ\Bin\QQ.exe"

//高级例子2
//介绍: 如果你要执行CMD命令行内容, 可以尝试使用本函数
//命令行: 命令行代码内容, 如果存在文件路径, 请给路径加单引号, 例如 "'C:\Program Files (x86)\Tencent\QQ\Bin\QQ.exe'"
Function zmRunCMD(命令行)
    Dim fs, tempFile, f, tempText 
    命令行 = Replace(命令行, "'", chr(34))
    Set fs = CreateObject("scripting.FileSystemObject")
    tempFile = fs.GetSpecialFolder(2) & "\" & fs.GetTempName
    RunApp "cmd.exe /c " & 命令行 &" > " & tempFile
    //如果命令行执行耗时较久, 请加长延时的时间
    Delay 1000
    If fs.FileExists(tempFile) Then 
        Set f = fs.openTextFile(tempFile, 1)
        tempText = f.ReadAll
        f.Close
        Set f = Nothing
    End If
    Set fs = Nothing
    zmRunCMD = tempText
End Function

//调用例子, 下面是执行dir命令行并输出结果
TracePrint zmRunCMD("dir")