zm.FindColor 超级找色

🎯功能

比 FindColor 寻找颜色 更加强大的命令, 具体特色如下

• 参数太多, 写的累? 所有参数都是可选的, 使你的代码更加简洁清晰
• 参数太多, 顺序记不住? 除了对象与范围是固定顺序外, 其他参数全部可以打乱顺序随便写
• 省略参数的默认值不理想? 可使用 zm.SetFindColor 设置FindColor默认参数 来自定义修改
• 担心一次找不到颜色? 自由设置限时循环查找时间, 提高成功率
• 画面变化太大, 相似度不好设置? 智能相似度帮你全自动查找
• 查找方向的数值总是记不住? 直接用中文 "左上","中心","右上","左下","右下",... 来代替
• 脚本出错找不到问题? 开启日志输出显示参数, 所有问题一目了然
• 找到后想等画面消失再继续下一步操作吗? 等待消失参数帮你解决这个烦恼
• 支持命令返回值与参数返回值, 你想怎么写, 就怎么写
• 返回值中有序号, 坐标, 还有对应的颜色值
• 支持对象参数写法, 将所有参数保存到一张表里, 直接传入该表
• 支持重写, 即传入对象参数后, 再写其他参数将会覆盖对应的对象数据
• 需要防检测点击功能? 推荐使用zm.FindColorTap 超级找色点击
• 需要遍历多个对象数组? 推荐使用zm.FindColorTable 超级找色遍历
• 需要返回所有找到的坐标? 推荐使用zm.FindColorEx 超级找色返回所有坐标

危险

本命令的方向参数是字符串型, 例如"左上"之类, 而按键自带命令的方向是数值型, 例如0之类, 如果直接复制按键命令的参数, 一定要记得修改方向参数!

📜语法

序号坐标颜色 = zm.FindColor([对象,][x1,y1,x2,y2,][颜色][,方向][,相似度[,智能相似度[,相似度步长]]][,查找次数][,是否点击][,点击坐标][,显示日志][,输出行号][,备注][,等待消失][,消失超时][,参数返回值])

📥参数

参数	数据类型	解释
对象	表	可选, 把所有参数放入一个table中传入, 若后面跟有其他参数, 则会对应覆盖对象数据
x1	数值型	可选, 查找范围的左上角x坐标, 省略默认为0
y1	数值型	可选, 查找范围的左上角y坐标, 省略默认为0
x2	数值型	可选, 查找范围的右下角x坐标, 省略默认为0
y2	数值型	可选, 查找范围的右下角y坐标, 省略默认为0
颜色	字符串	可选, 要查找的16进制颜色，格式为“BBGGRR”，多个颜色用“|”隔开，偏色使用“-”隔开，比如"FFFFFF-101010|123456"
方向	字符串	可选, 从指定方向开始查找, 省略默认为"左上", 支持["左上","中心","右上","左下","右下","上左","上右","下左","下右"]这几个值
相似度	数值型	可选, 对比查找的相似度小数, 省略默认为1.0, 取值范围[0, 1.0], 越高越相似
智能相似度	数值型	可选, 与相似度组成组成智能相似计算范围, 适合图色变化大的情况, 省略默认取值与相似度相同, 取值范围[0, 1.0], 越高越相似
相似度步长	数值型	可选, 智能相似度调节变化间隔, 必须写在相似度后面, 省略默认为0.05, 取值范围[0, 1.0]
超时时间	数值型	可选, 限时查找时间, 单位毫秒, 如果一次找不到, 可以限时循环查找, 省略默认为1
是否点击	布尔型	可选, 是否需要找到后自动点击该坐标, 支持[true, false]这两个值, 省略默认为false
点击坐标	字符串	可选, 点击修改后的坐标, 格式"±x,±y,t", 省略为找到的坐标, t是可选的, 表示点击后延时毫秒, 例如"100,100"表示固定点击坐标100,100, "+10,-10"表示偏移点击找到的x+10,y-10位置, "10,10,2000"表示点击10,10坐标后延时2000毫秒, 该参数会受zm.SetTap 设置超级点击影响
显示日志	字符串	可选, 输出调试日志信息, 省略默认为"隐藏", 支持 ["显示","显示找到", "显示没找到","隐藏","show", "showfind", "shownofind","hide"] 这几个值
输出行号	字符串	可选, 格式为"_"开头后跟行号, 比如"_10"表示第10行代码, 输出调试信息窗口显示第几行代码, 需开启显示日志才有效
备注	字符串	可选, 格式为"@"开头后跟内容, 在调试日志信息中加入该内容, 比如"@拾取屠龙刀", 若连续两个"@@"则表示在浮窗中显示信息, 需要开启显示日志才有效
等待消失	数值型	可选, 填写-1禁用或-2启用, -2表示找到后或点击后继续查找, 直到找不到或消失超时, 省略默认为-1, 启用后返回值将有miss键名, 值为true时表示成功消失, 值为false表示未消失
消失超时	数值型	可选, 填写负数, 表示等待消失的超时时间, 单位毫秒, 注意必须填写负数, 不可填-1和-2, 省略默认为-2000
参数返回值	表	可选, 只能传入数组变量名, 用于保存查找结果, 格式与命令返回值相同

📤返回

表 , 找到返回结果保存到表中, 格式为 {id, x, y, name, "id":id, "x":x, "y":y, "name":name, "miss":miss} , 没找到或出错返回null, 使用方法请看示例

💡示例

Import "zm.luae" //导入插件,只需执行一次
zm.Init  //初始化插件,只需执行一次

//--------------------初级用法--------------------//
Dim ret
//0.9表示相似度, 内置省略默认为1.0, 可自由设置
ret = zm.FindColor("00AAFF", 0.9)
If ret Then
    TracePrint "可以用以下3种格式获取返回值"
    TracePrint "找到颜色序号" & ret(0), "x=" & ret(1), "y=" & ret(2), "颜色=" & ret(3)
    TracePrint "找到颜色序号" & ret[1], "x=" & ret[2], "y=" & ret[3], "颜色=" & ret[4]
    TracePrint "找到颜色序号" & ret["id"], "x=" & ret["x"], "y=" & ret["y"], "颜色=" & ret["name"]
Else
    TracePrint "没有找到"
End If

//--------------------中级用法--------------------//
Dim 返回数组()
//参数返回值必须是任意数组的变量名, 注意括号写法
//范围省略默认为全屏, 若填写, 则4个数字必须全写
If zm.FindColor(100, 200, 300, 400, "00AAFF", 返回数组) Then
    TracePrint "可以用以下3种格式获取返回值"
    TracePrint "找到颜色序号" & 返回数组(0), "x=" & 返回数组(1), "y=" & 返回数组(2), "颜色=" & 返回数组(3)
    TracePrint "找到颜色序号" & 返回数组[1], "x=" & 返回数组[2], "y=" & 返回数组[3], "颜色=" & 返回数组[4]
    TracePrint "找到颜色序号" & 返回数组["id"], "x=" & 返回数组["x"], "y=" & 返回数组["y"], "颜色=" & 返回数组["name"]
Else
    TracePrint "没有找到"
End If

//--------------------高级用法--------------------//
//"00AAFF"颜色后面的可选参数全部可以打乱顺序任意填写或省略, 只要数据类型与格式正确即可, 详见上面参数介绍
//这句代码意思如下:
//在范围(100,200,300,400)里, 以相似度为(0.8)的设置, 从("中心")向四周循环限时2秒钟内查找颜色为("00AAFF")的点
//找到后退出循环查找, 并将找到的序号与坐标结果保存到数组变量(ret)与(返回数组)中
//同时开启日志的输出("显示")功能, 在当前脚本第("_36")行输出备注("@怪物1"), 查找结果与其他参数信息
ret = zm.FindColor(100, 200, 300, 400, "00AAFF", 0.8, 2000, "中心", "显示", "@怪物1", 返回数组, "_36")
If ret Then
    TracePrint "找到了"
Else
    TracePrint "没有找到"
End If

//--------------------对象用法--------------------//
//可以把所有参数放到一个表中, 颜色后面的可选参数一样可以打乱顺序任意填写或省略
//对象参数必须填写在第一个参数位置
//如果参数对象后面还有参数, 比如("_46"), 则表示重写对象里的("_36"), 使日志输出显示在46行
Dim 史莱姆 = {"00AAFF", 0.8, 2000, "显示", "@攻击史莱姆", 返回数组, "_46"}
zm.FindColor 史莱姆, 100, 200, 300, 400, "_46"

//--------------------修改默认值--------------------//
Dim IXYs()
//设置默认参数返回值IXYs, 若命令不填写参数返回值, 则默认保存在该变量中
//设置默认日志输出为显示状态, 后面所有 zm.FindColor() 都默认输出调试信息
//更多修改默认设置详见 zm.SetFindColor() 命令帮助
zm.SetFindColor {"ret":IXYs, "showlog":"显示"}
If zm.FindColor("00AAFF") Then
    TracePrint "可以用以下3种格式获取返回值"
    TracePrint "找到序号" & IXYs(0), "x=" & IXYs(1), "y=" & IXYs(2), "颜色=" & IXYs(3)
    TracePrint "找到序号" & IXYs[1], "x=" & IXYs[2], "y=" & IXYs[3], "颜色=" & IXYs[4]
    TracePrint "找到序号" & IXYs["id"], "x=" & IXYs["x"], "y=" & IXYs["y"], "颜色=" & IXYs["name"]
Else
    TracePrint "没有找到"
End If

📘备注

• 该命令用法灵活多变, 更多用法请大家自行摸索, 灵活使用输出日志可以事半功倍
• 偏色是微调，指对RBG三色分别确定取色范围。相似度是粗调，指对颜色整体做百分比判断。
• V1.1741: 加入命令
• V1.1745: 查找次数参数修改为超时参数, 加入自定义日志备注与行号, 其中设置相关的属性也有所变动
• V1.1746: 加入点击坐标参数
• V1.1750: 删除随机范围点击功能, 加入智能相似度参数
• V1.1802:
  • 支持zm.SetTap 设置超级点击的随机点击
  • 通过KeepCapture 截图至内存加快超级图色查找速度
  • 优化部分参数判定, 兼容更多乱序参数
  • 返回值加入找到颜色值
• V1.1803: 支持超级缩放命令, 点击功能只受是否点击参数影响
• V1.1804: 加入找到后等待消失可选参数
• V1.1813: 修复点击参数不继承zm.SetTap()设置延时问题, 感谢 likanglong 反馈
• V1.1818:
  • 修复由超级缩放命令引起的自动点击坐标0,0问题, 感谢 ersheep 反馈此BUG
  • 修复超级图色输出是否点击异常, 感谢 2578学员 反馈此BUG
• V2.1826: 为智能相似度增加另一种方便的写法, 旧语法依旧有效
• V2.1828: 若要点击找到坐标, 推荐使用zm.FindColorTap 超级找色点击
• V4.2042: 日志参数 showlog 加入 ["显示找到","显示没找到","showfind","shownofind"] 选项